'set novalue on'  /* force KEXX and its way of SIGNAL ON NOVALUE  */

/* Usage:         [MACRO] TV                                      */
/* Purpose:       TV replaces all blocks of lines between empty   */
/*                lines, where the first line starts with TV, by  */
/*                a single line REMOVED.  This is typically a B64 */
/*                encoded MicroSoft binary (magic MZ) in an mbox. */
/*                Any corresponding file name in a Content-Type:  */
/*                header is replaced by name="original.REMOVED"   */
/* Caveats:       Other binaries like image/gif are not replaced. */
/*                TV is only designed to simplify the most common */
/*                Microsoft MZ (base64 TV) and PKZIP (base64 UE)  */
/*                virus reports.                                  */
/* Requires:      Kedit 5.0               (Frank Ellermann, 2003) */

   WRAP = wrap.1()   ;  'nomsg change /<iframe/<!frame/ all'
   'wrap off'        ;  'locate :0 tag'   ;  N = 0 ;  M = 0

   do until rc <> 0
      'nomsg tfind blank'                 ;  if rc <> 0  then leave

      'next'         ;  LINE = curline.3()
      if abbrev( LINE, 'TV' ) = abbrev( LINE, 'UE' )  then iterate
      'next'         ;  'mark line reset'
      'tfind blank'  ;  if rc <> 0  then exit 1

      'up'           ;  'mark line'       ;  'del block'
      'up'           ;  'replace REMOVED' ;  N = N + 1

      'up 4'         ;  LINE = curline.3()
      if abbrev( translate( LINE ), 'CONTENT-TYPE: ' ) then do
         parse var LINE LINE 'name=' NAME
         if NAME <> '' then do
            if right( NAME, 1 ) = '"'
               then  NAME = strip( NAME, 'T', '"' ) || '.REMOVED"'
               else  NAME = NAME || '.REMOVED'
            'replace' LINE 'name=' NAME   ;  M = M + 1
         end
      end
      'up'
      do 8
         'more tag :' || LINE.1()         ;  'next'
      end
   end

   say N 'TV or UE blocks REMOVED (' || M 'names patched)'
   'wrap' WRAP       ;  'nomsg all tagged'
   if rc = 0 then do
      'nomsg tag /name=/ & ~/REMOVED/'
      if rc <> 0  then  'cmsg SAVE'
                  else  ':0 locate tagged'
   end
   exit rc